Folge 34 – Feature erstellen

In diesem Video werde ich euch zeigen, wie aus einer Skizze dann ein Volumen entstehen kann.

Und an dieser Stelle der Code der im Makro vorhanden ist.

Option Explicit
Sub main()
    Dim swApp As SldWorks.SldWorks
    Set swApp = Application.SldWorks
    Dim swModel As ModelDoc2
    Set swModel = swApp.ActiveDoc
    If swModel Is Nothing Then
        swApp.SendMsgToUser2 "Kein Dokument geladen.", swMessageBoxIcon_e.swMbStop, swMessageBoxBtn_e.swMbOk
        End
    End If
    If swModel.GetType <> swDocPART Then
        swApp.SendMsgToUser2 "Dieses Makro ist nur für Teil-Dateien gedacht.", swMessageBoxIcon_e.swMbStop, swMessageBoxBtn_e.swMbOk
        End
    End If
    Dim selected As Boolean
    selected = swModel.Extension.SelectByID2("Ebene vorne", "PLANE", 0, 0, 0, False, -1, Nothing, 0)
    Dim swSketchMgr As SketchManager
    Set swSketchMgr = swModel.SketchManager
    Dim enableSnapping As Boolean
    enableSnapping = swApp.GetUserPreferenceToggle(swUserPreferenceToggle_e.swSketchInference)
    swApp.SetUserPreferenceToggle swUserPreferenceToggle_e.swSketchInference, False
    swSketchMgr.InsertSketch True
    swSketchMgr.CreateCornerRectangle 0#, 0#, 0#, 0.15, 0.1, 0#
    swSketchMgr.InsertSketch True
    swApp.SetUserPreferenceToggle swUserPreferenceToggle_e.swSketchInference, enableSnapping
    Dim swFeatureManager As FeatureManager
    Set swFeatureManager = swModel.FeatureManager
    Dim swFeature As Feature
    Set swFeature = swFeatureManager.FeatureExtrusion3( _
                                    True, _
                                    False, _
                                    False, _
                                    swEndConditions_e.swEndCondBlind, _
                                    swEndConditions_e.swEndCondBlind, _
                                    0.05, _
                                    0#, _
                                    False, _
                                    False, _
                                    False, _
                                    False, _
                                    0#, _
                                    0#, _
                                    False, _
                                    False, _
                                    False, _
                                    False, _
                                    True, _
                                    True, _
                                    True, _
                                    swStartConditions_e.swStartSketchPlane, _
                                    0#, _
                                    False)
End Sub
Code-Sprache: VB.NET (vbnet)

Schreibe einen Kommentar

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert